C***********************************************************************
C   THIS ROUTINE COMPUTES THE LOG-LIKELIHOOD EQUATIONS AND THE
C   INFORMATION MATRIX FOR THE CURRENT PARAMETER VALUES IN PAR
C   FOR GROUPED DATA.
C***********************************************************************
      SUBROUTINE STATS
C***********************************************************************
C     DECLARATIONS
C***********************************************************************
      INCLUDE 'PARMTR.INC'
      DOUBLE PRECISION PCELL, CELL
      LOGICAL WARN
      INTEGER CNT
C***********************************************************************
C     COMMON STATEMENTS
C***********************************************************************
      DOUBLE PRECISION PAR, VCMAT, G, XLL
      COMMON /DPAR/ PAR(MAXPR2), VCMAT(MAXPAR,MAXPAR), G(MAXPAR),
     1    XLL, NPAR, INDEX
      COMMON /INTER/ K, CUT(MAXCEL), F(MAXCEL), NCUT, NKC(5),
     1    NK(5), RFREQ(5,MAXCEL), CCUT(5,MAXCEL)
      COMMON /PART/ PCELL(MAXCEL,MAXPAR), CELL(MAXCEL)
      COMMON /NUM/ XL(MAXLIN), WIDTH, N, CNT, CONV(3), VARN, IDF, WARN
      XN=FLOAT(CNT)
C
C   FIRST COMPUTE G(I),I=1,...NPAR,WHICH ARE THE LOG-LIKELIHOOD EQUATION
C
      DO 20 J=1,NPAR
         G(J)=0.0
         DO 10 I=1,K
   10       G(J)=G(J)+(F(I)*PCELL(I,J)/CELL(I))
   20    CONTINUE
C
C   NOW COMPUTE THE INFORMATION MATRIX
C
      DO 40 J=1,NPAR
         DO 40 M=J,NPAR
         VCMAT(J,M)=0.0
         DO 30 I=1,K
   30       VCMAT(J,M)=VCMAT(J,M)+PCELL(I,J)*PCELL(I,M)/CELL(I)
         VCMAT(J,M)=XN*VCMAT(J,M)
         VCMAT(M,J)=VCMAT(J,M)
   40    CONTINUE
      RETURN
      END