C***********************************************************
C   THIS SUBROUTINE COMPUTES THE MAXIMUM LIKELIHOOD ESTIMATE OF THE
C   PARAMETER C, AND ASSOCIATED SUMMARY STATISTICS IN THE GENERALIZED
C   HAYNE MODEL FOR LINE TRANSECTS. THE PROBABILITY INTEGRAL
C   TRANSFORMATION IS ALSO COMPUTED.
C
C   NOTATION:
C   N              SAMPLE SIZE.
C   X              AN ARRAY OF THE SINES OF THE THETA(I) VALUES.
C   U              AN ARRAY OF THE PROBABILITY INTEGRAL TRANSFORMED
C                  VALUES OF THE X(I), USING  C.
C   C           THE ML ESTIMATOR OF C.
C   VARC           THE ESTIMATED SAMPLING VARIANCE OF C.
C***********************************************************
      SUBROUTINE ELLIPS (X,C,VARC,N)
C***********************************************************************
C     DECLARATIONS
C***********************************************************************
      INCLUDE 'PARMTR.INC'
      REAL  X(1)
C***********************************************************************
C     COMMON STATEMENTS
C***********************************************************************
      COMMON /TS/ U(MAXOBJ)
C
C   FIRST COMPUTE THE MEAN OF THE X(I)
C
      C=0.0
      XN=FLOAT(N)
      DO 10 I=1,N
   10 C=C+X(I)
      C=(XN/C)-1.0
C
C   USING THIS STARTING VALUE FOR C, THE METHOD OF SCORING IS
C   USED TO FIND THE ML ESTIMATOR OF C.
C
      DO 30 J=1,100
      G=0.0
      Q=(C*C)-1.0
      QQ=3.0*C
      DO 20 I=1,N
      XSQ=X(I)*X(I)
      TOP=QQ*XSQ
      BOTTOM=1.0+Q*XSQ
   20 G=G+(TOP/BOTTOM)
      G=(XN/C)-G
      VARC=1.25*C*C/XN
      DELTA=VARC*G
      C=C+DELTA
      IF (ABS(DELTA).LT.0.1E-7) GO TO 40
   30 CONTINUE
C
C   AT THIS POINT WE HAVE THE ML ESTIMATE OF C AND ALSO ITS
C   SAMPLING VARIANCE. NOW COMPUTE THE U(I).
C
   40 Q=(C*C)-1.0
      DO 50 I=1,N
      QQ=X(I)
      QQSQ=QQ*QQ
      TOP=C*QQ
      BOTTOM=1.0+Q*QQSQ
   50 U(I)=TOP/SQRT(BOTTOM)
      RETURN
      END